在http://windyma.blog.51cto.com/661702/1967027  文章，已做好用戶腳本基礎(chǔ)上進(jìn)行設(shè)置

創(chuàng)新互聯(lián)是一家專業(yè)提供石屏企業(yè)網(wǎng)站建設(shè),專注與成都做網(wǎng)站、網(wǎng)站制作、H5網(wǎng)站設(shè)計(jì)、小程序制作等業(yè)務(wù)。10年已為石屏眾多企業(yè)、政府機(jī)構(gòu)等服務(wù)。創(chuàng)新互聯(lián)專業(yè)網(wǎng)站制作公司優(yōu)惠進(jìn)行中。

首先設(shè)置用戶背景桌面是微軟件的Bginfo工具，而kixtart只是用來獲取用戶屏幕的分辨率，根據(jù)不同屏幕的分辨率再來調(diào)用Bginfo工具來設(shè)置不同分辨率的背景圖片,以此保證圖片不會變形。

第一，在域\\nccn.int\NETLOGON 共享下新建Bginfo目錄，把Bginfo.exe工具及不同分辨率的背景圖全復(fù)制到Bginfo目錄下。

第二，用Bginfo.exe工具設(shè)置上桌面上需要顯示內(nèi)容（如我的，右上角是電話撥打簡單說明，右下角是計(jì)算機(jī)相關(guān)信息及IT的聯(lián)系電話），點(diǎn)Backgroud,在use these setting:下選擇不同的分辨率的背景圖文件，確認(rèn)后。保存在\\nccn.int\NETLOGON\Bginfo下，名為1280-1024.bgi文件（假如這個(gè)背景圖文件的分辨率為1280x1024），其它分辨率背景一樣操作

第三，準(zhǔn)備后，在\\nccn.int\NETLOGON\下新建腳本文件Function.kix用于定義一個(gè)獲取用戶屏幕的分辨率的funciton,以便于kixtart.kix調(diào)用，如下內(nèi)容：

;此function來自kixtart官方的案例，根據(jù)自行需要作了一些更改 

Function GetScreenRes()
  Dim $Dev,$Idx,$RKey,$ScreenXRes,$ScreenYRes,$SType
  $GetScreenRes = ''
  If @InWin = 1 
    If Split(@ProductType)[1] <> "NT"
      $Dev = Split('' + WMIQuery("VideoModeDescription","Win32_VideoController"))
      If UBound($Dev) > 1
        $GetScreenRes = $Dev[0] + "-" + $Dev[2]
      EndIf
    Else
      $RKey="HKLM\SYSTEM\CurrentControlSet\Hardware Profiles\Current\System\CurrentControlSet\Services"
      $Dev = "\Device0"
      If KeyExist($RKey)
        $Idx = 0
        Do
          $SType = EnumKey($RKey,$Idx)
          If @Error = 0 And $SType <> "VgaSave"
              $ScreenXRes = '' + ReadValue($RKey + "\" + $SType + $Dev,"DefaultSettings.XResolution")
              $ScreenYRes = '' + ReadValue($RKey + "\" + $SType + $Dev,"DefaultSettings.YResolution")
          Else
            $Idx = $Idx + 1
          EndIf
        Until @Error Or $ScreenXRes
        If $ScreenXRes
          $GetScreenRes = $ScreenXRes + '-' + $ScreenYRes
        EndIf
      EndIf
    EndIf
  Else
    $RKey="HKLM\Config\0001\Display\Settings"
    If KeyExist($RKey)
      $GetScreenRes = ReadValue($RKey,"Resolution")
    EndIf
  EndIf
EndFunction
FUNCTION WMIQuery($what,$where, optional $computer)
  dim $strQuery, $objEnumerator, $value
  if not $computer  $computer="@WKSTA"  endif
  $strQuery = "Select $what From $where"
  $SystemSet = GetObject("winmgmts:{impersonationLevel=impersonate}!//$computer")
  $objEnumerator = $SystemSet.ExecQuery($strQuery)
  For Each $objInstance in $objEnumerator
    If @Error = 0 and $objInstance <> ""
      $=execute("$$value = $$objInstance.$what")
      $WMIQuery="$value"+""+"$WMIQuery"
      EndIf
    Next
  $WMIQuery=left($WMIQuery,len($WMIQuery)-1)
  exit @error
ENDFUNCTION

第四，定義好function后，我們在kixtart.kix中添加如下內(nèi)容：

;首先調(diào)用自定義的Function.kix

CALL "%logonserver%\NETLOGON\Function.kix"
;取得用戶屏幕的分辨率并賦給變量$ScreenRes
$ScreenRes = GetScreenRes()
;調(diào)用bginfo.exe工具
IF EXIST("%logonserver%\netlogon\Bginfo\$ScreenRes.bgi")
RUN "%logonserver%\netlogon\Bginfo\bginfo.exe /nolicprompt %logonserver%\netlogon\Bginfo\$ScreenRes.bgi /timer:00"
ELSE
RUN "%logonserver%\netlogon\Bginfo\bginfo.exe /nolicprompt %logonserver%\netlogon\Bginfo\wallpaper.bgi /timer:00"
ENDIF

新聞標(biāo)題：AD腳本kixtart運(yùn)用之四（用戶桌面背景）
網(wǎng)站URL：http://aaarwkj.com/article0/igccio.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供搜索引擎優(yōu)化、網(wǎng)站制作、小程序開發(fā)、動態(tài)網(wǎng)站、網(wǎng)站設(shè)計(jì)、云服務(wù)器

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請盡快告知，我們將會在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場，如需處理請聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來源： 創(chuàng)新互聯(lián)