操作系統(tǒng)--局部段描述符表的使用
Q:什么是LDT
A.局部段描述符表
1.本質(zhì)是一個段描述符表，用于定義段描述符
2.與GDT類似，可以看作"段描述符的數(shù)組"
3.通過定義選擇子訪問局部描述符表中的元素
局部段描述符選擇子
局部段描述符表
需要注意的是
1.局部段描述符表需要在全局段描述符表中注冊(增加描述符)
2.通過對應(yīng)的選擇子加載局部段描述符(lldt)
3.局部段描述符從第0項開始使用
在這里會出現(xiàn)一個問題-LDT具體用來干什么？同時為什么還需要一個"額外的"段描述符？
LDT的意義主要體現(xiàn)在兩個方面：代碼層次的意義-分級管理功能相同意義不同的段(多個代碼段)；系統(tǒng)層次的意義-實現(xiàn)多任務(wù)的基礎(chǔ)要素(每個任務(wù)對應(yīng)一系列不同的段)
B.LDT的定義與使用
1.定義獨立功能相關(guān)的段(代碼段，數(shù)據(jù)段，棧段)
2.將目標(biāo)段描述符組成局部段描述表(LDT)
3.為各個段描述符定義選擇子(SA_TIL)
4.在GDT中定義LDT的段描述符，并定義選擇子
C.LDT的定義與使用
代碼實現(xiàn)-要在inc.asm中對DA_LDT equ 0x82進(jìn)行定義要不然會在運行時出現(xiàn)錯誤
專注于為中小企業(yè)提供網(wǎng)站制作、成都網(wǎng)站制作服務(wù),電腦端+手機(jī)端+微信端的三站合一,更高效的管理,為中小企業(yè)平遙免費做網(wǎng)站提供優(yōu)質(zhì)的服務(wù)。我們立足成都，凝聚了一批互聯(lián)網(wǎng)行業(yè)人才，有力地推動了成百上千家企業(yè)的穩(wěn)健成長，幫助中小企業(yè)通過網(wǎng)站建設(shè)實現(xiàn)規(guī)模擴(kuò)充和轉(zhuǎn)變。
%include "inc.asm"
org 0x9000
jmp ENTRY_SEGMENT
[section .gdt]
; GDT definition
; 段基址， 段界限， 段屬性
GDT_ENTRY : Descriptor 0, 0, 0
CODE32_DESC : Descriptor 0, Code32SegLen - 1, DA_C + DA_32
VIDEO_DESC : Descriptor 0xB8000, 0x07FFF, DA_DRWA + DA_32
DATA32_DESC : Descriptor 0, Data32SegLen - 1, DA_DR + DA_32
STACK32_DESC : Descriptor 0, TopOfStack32, DA_DRW + DA_32
CODE16_DESC : Descriptor 0, 0xFFFF, DA_C
UPDATE_DESC : Descriptor 0, 0xFFFF, DA_DRW
TASK_A_LDT_DESC : Descriptor 0, TaskALdtLen - 1, DA_LDT
; GDT end
GdtLen equ $ - GDT_ENTRY
GdtPtr:
dw GdtLen - 1
dd 0
; GDT Selector
Code32Selector equ (0x0001 << 3) + SA_TIG + SA_RPL0
VideoSelector equ (0x0002 << 3) + SA_TIG + SA_RPL0
Data32Selector equ (0x0003 << 3) + SA_TIG + SA_RPL0
Stack32Selector equ (0x0004 << 3) + SA_TIG + SA_RPL0
Code16Selector equ (0x0005 << 3) + SA_TIG + SA_RPL0
UpdateSelector equ (0x0006 << 3) + SA_TIG + SA_RPL0
TaskALdtSelector equ (0x0007 << 3) + SA_TIG + SA_RPL0
; end of [section .gdt]
TopOfStack16 equ 0x7c00
[section .dat]
[bits 32]
DATA32_SEGMENT:
DTOS db "D.T.OS!", 0
DTOS_OFFSET equ DTOS - $$
HELLO_WORLD db "Hello World!", 0
HELLO_WORLD_OFFSET equ HELLO_WORLD - $$
Data32SegLen equ $ - DATA32_SEGMENT
[section .s16]
[bits 16]
ENTRY_SEGMENT:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, TopOfStack16
mov [BACK_TO_REAL_MODE + 3], ax
; initialize GDT for 32 bits code segment
mov esi, CODE32_SEGMENT
mov edi, CODE32_DESC
call InitDescItem
mov esi, DATA32_SEGMENT
mov edi, DATA32_DESC
call InitDescItem
mov esi, STACK32_SEGMENT
mov edi, STACK32_DESC
call InitDescItem
mov esi, CODE16_SEGMENT
mov edi, CODE16_DESC
call InitDescItem
mov esi, TASK_A_LDT_ENTRY
mov edi, TASK_A_LDT_DESC
call InitDescItem
mov esi, TASK_A_CODE32_SEGMENT
mov edi, TASK_A_CODE32_DESC
call InitDescItem
mov esi, TASK_A_DATA32_SEGMENT
mov edi, TASK_A_DATA32_DESC
call InitDescItem
mov esi, TASK_A_STACK32_SEGMENT
mov edi, TASK_A_STACK32_DESC
call InitDescItem
; initialize GDT pointer struct
mov eax, 0
mov ax, ds
shl eax, 4
add eax, GDT_ENTRY
mov dword [GdtPtr + 2], eax
; 1. load GDT
lgdt [GdtPtr]
; 2. close interrupt
cli
; 3. open A20
in al, 0x92
or al, 00000010b
out 0x92, al
; 4. enter protect mode
mov eax, cr0
or eax, 0x01
mov cr0, eax
; 5. jump to 32 bits code
jmp dword Code32Selector : 0
BACK_ENTRY_SEGMENT:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, TopOfStack16
in al, 0x92
and al, 11111101b
out 0x92, al
sti
mov bp, HELLO_WORLD
mov cx, 12
mov dx, 0
mov ax, 0x1301
mov bx, 0x0007
int 0x10
jmp $
; esi --> code segment label
; edi --> descriptor label
InitDescItem:
push eax
mov eax, 0
mov ax, cs
shl eax, 4
add eax, esi
mov word [edi + 2], ax
shr eax, 16
mov byte [edi + 4], al
mov byte [edi + 7], ah
pop eax
ret
[section .s16]
[bits 16]
CODE16_SEGMENT:
mov ax, UpdateSelector
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ss, ax
mov eax, cr0
and al, 11111110b
mov cr0, eax
BACK_TO_REAL_MODE:
jmp 0 : BACK_ENTRY_SEGMENT
Code16SegLen equ $ - CODE16_SEGMENT
[section .s32]
[bits 32]
CODE32_SEGMENT:
mov ax, VideoSelector
mov gs, ax
mov ax, Stack32Selector
mov ss, ax
mov eax, TopOfStack32
mov esp, eax
mov ax, Data32Selector
mov ds, ax
mov ebp, DTOS_OFFSET
mov bx, 0x0C
mov dh, 12
mov dl, 33
call PrintString
mov ebp, HELLO_WORLD_OFFSET
mov bx, 0x0C
mov dh, 13
mov dl, 31
call PrintString
mov ax, TaskALdtSelector
lldt ax
jmp TaskACode32Selector : 0
; jmp Code16Selector : 0
; ds:ebp --> string address
; bx --> attribute
; dx --> dh : row, dl : col
PrintString:
push ebp
push eax
push edi
push cx
push dx
print:
mov cl, [ds:ebp]
cmp cl, 0
je end
mov eax, 80
mul dh
add al, dl
shl eax, 1
mov edi, eax
mov ah, bl
mov al, cl
mov [gs:edi], ax
inc ebp
inc dl
jmp print
end:
pop dx
pop cx
pop edi
pop eax
pop ebp
ret
Code32SegLen equ $ - CODE32_SEGMENT
[section .gs]
[bits 32]
STACK32_SEGMENT:
times 1024 * 4 db 0
Stack32SegLen equ $ - STACK32_SEGMENT
TopOfStack32 equ Stack32SegLen - 1
; ==========================================
;
; Task A Code Segment
;
; ==========================================
[section .task-a-ldt]
; Task A LDT definition
; 段基址, 段界限, 段屬性
TASK_A_LDT_ENTRY:
TASK_A_CODE32_DESC : Descriptor 0, TaskACode32SegLen - 1, DA_C + DA_32
TASK_A_DATA32_DESC : Descriptor 0, TaskAData32SegLen - 1, DA_DR + DA_32
TASK_A_STACK32_DESC : Descriptor 0, TaskAStack32SegLen - 1, DA_DRW + DA_32
TaskALdtLen equ $ - TASK_A_LDT_ENTRY
; Task A LDT Selector
TaskACode32Selector equ (0x0000 << 3) + SA_TIL + SA_RPL0
TaskAData32Selector equ (0x0001 << 3) + SA_TIL + SA_RPL0
TaskAStack32Selector equ (0x0002 << 3) + SA_TIL + SA_RPL0
[section .task-a-dat]
[bits 32]
TASK_A_DATA32_SEGMENT:
TASK_A_STRING db "This is Task A!", 0
TASK_A_STRING_OFFSET equ TASK_A_STRING - $$
TaskAData32SegLen equ $ - TASK_A_DATA32_SEGMENT
[section .task-a-gs]
[bits 32]
TASK_A_STACK32_SEGMENT:
times 1024 db 0
TaskAStack32SegLen equ $ - TASK_A_STACK32_SEGMENT
TaskATopOfStack32 equ TaskAStack32SegLen - 1
[section .task-a-s32]
[bits 32]
TASK_A_CODE32_SEGMENT:
mov ax, VideoSelector
mov gs, ax
mov ax, TaskAStack32Selector
mov ss, ax
mov eax, TaskATopOfStack32
mov esp, eax
mov ax, TaskAData32Selector
mov ds, ax
mov ebp, TASK_A_STRING_OFFSET
mov bx, 0x0C
mov dh, 14
mov dl, 29
call PrintString
jmp $
; ds:ebp --> string address
; bx --> attribute
; dx --> dh : row, dl : col
TaskACode32SegLen equ $ - TASK_A_CODE32_SEGMENT
運行結(jié)果
該處的運行結(jié)果
從運行結(jié)果可以得知并沒有打印出自定義的字符串，還是打印之前的結(jié)果，同時發(fā)現(xiàn)還存在一個錯誤，就是CPU進(jìn)行了重置，但是取消掉call PrintString 這個操作，會發(fā)現(xiàn)存在的錯誤消失了，這個函數(shù)是保護(hù)模式下的函數(shù)在這里調(diào)用出現(xiàn)錯誤的原因是屬于其它段的，不屬于現(xiàn)在的段，代碼段發(fā)生了跳轉(zhuǎn)，選擇子不一樣了。可以進(jìn)行改進(jìn)的是將之前的打印函數(shù)復(fù)制粘貼一份到現(xiàn)在的段中，需要注意的是要將名字進(jìn)行修改，不然會出現(xiàn)錯誤
改正后的代碼，注意jmp Code16Selector : 0命令會返回實模式打印Hello World及打印結(jié)果
D.多任務(wù)程序設(shè)計的實現(xiàn)思路
從這張圖可以聯(lián)想出-在保護(hù)模式下的不同段之間如何進(jìn)行代碼復(fù)用？
小結(jié)
1.局部段描述符表用于組織功能相關(guān)的段
2.局部段描述符表需要加載后才能正常使用
3.局部段描述符表必須在全局段描述符表中注冊
4.通過局部段描述符表的選擇子對其進(jìn)行訪問
5.局部段描述符表是實現(xiàn)多任務(wù)的基礎(chǔ)
標(biāo)題名稱：操作系統(tǒng)--局部段描述符表的使用
當(dāng)前地址：http://aaarwkj.com/article12/ipdidc.html
成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供企業(yè)網(wǎng)站制作、建站公司、軟件開發(fā)、小程序開發(fā)、品牌網(wǎng)站建設(shè)、自適應(yīng)網(wǎng)站
聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請盡快告知，我們將會在第一時間刪除。文章觀點不代表本網(wǎng)站立場，如需處理請聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時需注明來源： 創(chuàng)新互聯(lián)
- 選擇一家好的網(wǎng)頁設(shè)計公司幾點建議 2022-03-27
- 怎么選擇一家合適的網(wǎng)頁設(shè)計公司 2021-09-05
- 專業(yè)的網(wǎng)頁設(shè)計公司,成都網(wǎng)頁設(shè)計公司 2016-09-13
- 網(wǎng)頁設(shè)計公司分享手機(jī)網(wǎng)站建設(shè)時的細(xì)節(jié) 2016-11-11
- 鹽城網(wǎng)頁設(shè)計公司告訴你企業(yè)中英文網(wǎng)站該如何建設(shè) 2020-02-18
- 成都網(wǎng)頁設(shè)計公司怎樣開展網(wǎng)站制作？ 2023-02-08
- 網(wǎng)頁設(shè)計公司：面包屑導(dǎo)航優(yōu)化的必要性 2016-10-08
- 北京網(wǎng)頁設(shè)計公司:了解客戶需求 做有效益的網(wǎng)站 2016-10-29
- 如何在網(wǎng)上找到江蘇網(wǎng)頁設(shè)計公司 2020-11-25
- 建站價格影響因素有哪些-成都網(wǎng)頁設(shè)計公司 2023-03-02
- 北京比較好的網(wǎng)頁設(shè)計公司！ 2018-09-05
- 如何選擇網(wǎng)頁設(shè)計公司？ 2015-01-06