awk是行處理器: 相比較屏幕處理的優(yōu)點(diǎn)，在處理龐大文件時(shí)不會(huì)出現(xiàn)內(nèi)存溢出或是處理緩慢的問題，通常用來格式化文本信息

為博興等地區(qū)用戶提供了全套網(wǎng)頁設(shè)計(jì)制作服務(wù)，及博興網(wǎng)站建設(shè)行業(yè)解決方案。主營(yíng)業(yè)務(wù)為網(wǎng)站設(shè)計(jì)、成都網(wǎng)站設(shè)計(jì)、博興網(wǎng)站設(shè)計(jì)，以傳統(tǒng)方式定制建設(shè)網(wǎng)站，并提供域名空間備案等一條龍服務(wù)，秉承以專業(yè)、用心的態(tài)度為用戶提供真誠的服務(wù)。我們深信只要達(dá)到每一位用戶的要求，就會(huì)得到認(rèn)可，從而選擇與我們長(zhǎng)期合作。這樣，我們也可以走得更遠(yuǎn)！

awk處理過程: 依次對(duì)每一行進(jìn)行處理，然后輸出

awk命令形式:

awk [-F|-f|-v] ‘BEGIN{} //{command1; command2} END{}’ file

 [-F|-f|-v]  大參數(shù)，-F指定分隔符，-f調(diào)用腳本，-v定義變量 var=value

'  '      引用代碼塊

BEGIN  初始化代碼塊，在對(duì)每一行進(jìn)行處理之前，初始化代碼，主要是引用全局變量，設(shè)置FS分隔符

//      匹配代碼塊，可以是字符串或正則表達(dá)式

{}      命令代碼塊，包含一條或多條命令

；      多條命令使用分號(hào)分隔

END    結(jié)尾代碼塊，在對(duì)每一行進(jìn)行處理之后再執(zhí)行的代碼塊，主要是進(jìn)行最終計(jì)算或輸出結(jié)尾摘要信息

特殊要點(diǎn):

$0      表示整個(gè)當(dāng)前行

$1      每行第一個(gè)字段

NF      字段數(shù)量變量

NR      每行的記錄號(hào)，多文件記錄遞增

FNR     與NR類似，不過多文件記錄不遞增，每個(gè)文件都從1開始

\t       制表符

\n      換行符

FS      BEGIN時(shí)定義分隔符

RS       輸入的記錄分隔符， 默認(rèn)為換行符(即文本是按一行一行輸入)

~       匹配，與==相比不是精確比較

!~      不匹配，不精確比較

==     等于，必須全部相等，精確比較

!=      不等于，精確比較

&&　   邏輯與

||       邏輯或

+       匹配時(shí)表示1個(gè)或1個(gè)以上

/[0-9][0-9]+/  兩個(gè)或兩個(gè)以上數(shù)字

/[0-9][0-9]*/   一個(gè)或一個(gè)以上數(shù)字

FILENAME 文件名

OFS    輸出字段分隔符， 默認(rèn)也是空格，可以改為制表符等

ORS    輸出的記錄分隔符，默認(rèn)為換行符,即處理結(jié)果也是一行一行輸出到屏幕

-F'[:#/]'  定義三個(gè)分隔符

print & $0

print 是awk打印指定內(nèi)容的主要命令

awk '{print}'  /etc/passwd  ==   awk '{print $0}'  /etc/passwd

awk '{print " "}' /etc/passwd                                           //不輸出passwd的內(nèi)容，而是輸出相同個(gè)數(shù)的空行，進(jìn)一步解釋了awk是一行一行處理文本

awk '{print "a"}'   /etc/passwd                                        //輸出相同個(gè)數(shù)的a行，一行只有一個(gè)a字母

awk -F":" '{print $1}'  /etc/passwd

awk -F: '{print $1; print $2}'   /etc/passwd                   //將每一行的前二個(gè)字段，分行輸出，進(jìn)一步理解一行一行處理文本

awk  -F: '{print $1,$3,$6}' OFS="\t" /etc/passwd       //輸出字段1,3,6，以制表符作為分隔符

-f指定腳本文件

awk -f script.awk  file

BEGIN{

FS=":"

}

{print $1}        //效果與awk -F":" '{print $1}'相同,只是分隔符使用FS在代碼自身中指定

awk 'BEGIN{X=0} /^$/{ X+=1 } END{print "I find",X,"blank lines."}' test

I find 4 blank lines.

 ls -l|awk 'BEGIN{sum=0} !/^d/{sum+=$5} END{print "total size is",sum}'           //計(jì)算文件大小

total size is 17487

-F指定分隔符

$1 指指定分隔符后，第一個(gè)字段，$3第三個(gè)字段， \t是制表符

一個(gè)或多個(gè)連續(xù)的空格或制表符看做一個(gè)定界符，即多個(gè)空格看做一個(gè)空格

awk -F":" '{print $1}'  /etc/passwd

awk -F":" '{print $1 $3}'  /etc/passwd             //$1與$3相連輸出，不分隔

awk -F":" '{print $1,$3}'  /etc/passwd            //多了一個(gè)逗號(hào)，$1與$3使用空格分隔

awk -F":" '{print $1 " " $3}'  /etc/passwd          //$1與$3之間手動(dòng)添加空格分隔

awk -F":" '{print "Username:" $1 "\t\t Uid:" $3 }' /etc/passwd    //自定義輸出

awk -F: '{print NF}' /etc/passwd                 //顯示每行有多少字段

awk -F: '{print $NF}' /etc/passwd                //將每行第NF個(gè)字段的值打印出來

 awk -F: 'NF==4 {print }' /etc/passwd             //顯示只有4個(gè)字段的行

awk -F: 'NF>2{print $0}' /etc/passwd             //顯示每行字段數(shù)量大于2的行

awk '{print NR,$0}' /etc/passwd                   //輸出每行的行號(hào)

awk -F: '{print NR,NF,$NF,"\t",$0}' /etc/passwd    //依次打印行號(hào)，字段數(shù)，最后字段值，制表符，每行內(nèi)容

awk -F: 'NR==5{print}'  /etc/passwd              //顯示第5行

awk -F: 'NR==5 || NR==6{print}'  /etc/passwd     //顯示第5行和第6行

route -n|awk 'NR!=1{print}'                     //不顯示第一行

//匹配代碼塊

//純字符匹配  !//純字符不匹配 ~//字段值匹配   !~//字段值不匹配  ~/a1|a2/字段值匹配a1或a2

awk '/mysql/' /etc/passwd

awk '/mysql/{print }' /etc/passwd

awk '/mysql/{print $0}' /etc/passwd          //三條指令結(jié)果一樣

awk '!/mysql/{print $0}' /etc/passwd          //輸出不匹配mysql的行

awk '/mysql|mail/{print}' /etc/passwd

awk '!/mysql|mail/{print}' /etc/passwd

awk -F: '/mail/,/mysql/{print}' /etc/passwd     //區(qū)間匹配

awk '/[2][7][7]*/{print $0}' /etc/passwd        //匹配包含27為數(shù)字開頭的行，如27，277，2777...

awk -F: '$1~/mail/{print $1}' /etc/passwd      //$1匹配指定內(nèi)容才顯示

awk -F: '{if($1~/mail/) print $1}' /etc/passwd   //與上面相同

awk -F: '$1!~/mail/{print $1}' /etc/passwd      //不匹配

awk -F: '$1!~/mail|mysql/{print $1}' /etc/passwd

IF語句

必須用在{}中，且比較內(nèi)容用()擴(kuò)起來

awk -F: '{if($1~/mail/) print $1}' /etc/passwd                    //簡(jiǎn)寫

awk -F: '{if($1~/mail/) {print $1}}'  /etc/passwd                  //全寫

awk -F: '{if($1~/mail/) {print $1} else {print $2}}' /etc/passwd       //if...else...

條件表達(dá)式

==  !=  >  >=

awk -F":" '$1=="mysql"{print $3}' /etc/passwd

awk -F":" '{if($1=="mysql") print $3}' /etc/passwd      //與上面相同

awk -F":" '$1!="mysql"{print $3}' /etc/passwd         //不等于

awk -F":" '$3>1000{print $3}' /etc/passwd            //大于

awk -F":" '$3>=100{print $3}' /etc/passwd            //大于等于

awk -F":" '$3<1{print $3}' /etc/passwd                //小于

awk -F":" '$3<=1{print $3}' /etc/passwd             //小于等于

邏輯運(yùn)算符

&&　||

awk -F: '$1~/mail/ && $3>8 {print }' /etc/passwd     //邏輯與，$1匹配mail，并且$3>8

awk -F: '{if($1~/mail/ && $3>8) print }' /etc/passwd

awk -F: '$1~/mail/ || $3>1000 {print }' /etc/passwd    //邏輯或

awk -F: '{if($1~/mail/ || $3>1000) print }' /etc/passwd

數(shù)值運(yùn)算

awk -F: '$3 > 100' /etc/passwd

awk -F: '$3 > 100 || $3 < 5' /etc/passwd

awk -F: '$3+$4 > 200' /etc/passwd

awk -F: '/mysql|mail/{print $3+10}' /etc/passwd           //第三個(gè)字段加10打印

awk -F: '/mysql/{print $3-$4}' /etc/passwd               //減法

awk -F: '/mysql/{print $3*$4}' /etc/passwd               //求乘積

awk '/MemFree/{print $2/1024}' /proc/meminfo          //除法

awk '/MemFree/{print int($2/1024)}' /proc/meminfo      //取整

輸出分隔符OFS

awk '$6 ~ /FIN/ || NR==1 {print NR,$4,$5,$6}' OFS="\t" netstat.txt

awk '$6 ~ /WAIT/ || NR==1 {print NR,$4,$5,$6}' OFS="\t" netstat.txt

//輸出字段6匹配WAIT的行，其中輸出每行行號(hào)，字段4，5,6，并使用制表符分割字段

輸出處理結(jié)果到文件

①在命令代碼塊中直接輸出    route -n|awk 'NR!=1{print > "./fs"}'

②使用重定向進(jìn)行輸出       route -n|awk 'NR!=1{print}'  > ./fs

格式化輸出

netstat -anp|awk '{printf "%-8s %-8s %-10s\n",$1,$2,$3}'

printf表示格式輸出

%格式化輸出分隔符

-8長(zhǎng)度為8個(gè)字符

s表示字符串類型

打印每行前三個(gè)字段，指定第一個(gè)字段輸出字符串類型(長(zhǎng)度為8)，第二個(gè)字段輸出字符串類型(長(zhǎng)度為8),

第三個(gè)字段輸出字符串類型(長(zhǎng)度為10)

netstat -anp|awk '$6=="LISTEN" || NR==1 {printf "%-10s %-10s %-10s \n",$1,$2,$3}'

netstat -anp|awk '$6=="LISTEN" || NR==1 {printf "%-3s %-10s %-10s %-10s \n",NR,$1,$2,$3}'

IF語句

awk -F: '{if($3>100) print "large"; else print "small"}' /etc/passwd

small

small

small

large

small

small

awk -F: 'BEGIN{A=0;B=0} {if($3>100) {A++; print "large"} else {B++; print "small"}} END{print A,"\t",B}' /etc/passwd

                                                                                                                 //ID大于100,A加1，否則B加1

awk -F: '{if($3<100) next; else print}' /etc/passwd             //小于100跳過，否則顯示

awk -F: 'BEGIN{i=1} {if(i<NF) print NR,NF,i++ }' /etc/passwd

awk -F: 'BEGIN{i=1} {if(i<NF) {print NR,NF} i++ }' /etc/passwd

另一種形式

awk -F: '{print ($3>100 ? "yes":"no")}'  /etc/passwd

awk -F: '{print ($3>100 ? $3":\tyes":$3":\tno")}'  /etc/passwd

while語句

awk -F: 'BEGIN{i=1} {while(i<NF) print NF,$i,i++}' /etc/passwd

7 root 1

7 x 2

7 0 3

7 0 4

7 root 5

7 /root 6

數(shù)組

netstat -anp|awk 'NR!=1{a[$6]++} END{for (i in a) print i,"\t",a[i]}'

netstat -anp|awk 'NR!=1{a[$6]++} END{for (i in a) printf "%-20s %-10s %-5s \n", i,"\t",a[i]}'

9523                1

9929                1

LISTEN               6

7903                1

3038/cupsd          1

7913                1

10837               1

9833                1

應(yīng)用1

awk -F: '{print NF}' helloworld.sh                              //輸出文件每行有多少字段

awk -F: '{print $1,$2,$3,$4,$5}' helloworld.sh                  //輸出前5個(gè)字段

awk -F: '{print $1,$2,$3,$4,$5}' OFS='\t' helloworld.sh         //輸出前5個(gè)字段并使用制表符分隔輸出

awk -F: '{print NR,$1,$2,$3,$4,$5}' OFS='\t' helloworld.sh      //制表符分隔輸出前5個(gè)字段，并打印行號(hào)

應(yīng)用2

awk -F'[:#]' '{print NF}'  helloworld.sh                            //指定多個(gè)分隔符: #，輸出每行多少字段

awk -F'[:#]' '{print $1,$2,$3,$4,$5,$6,$7}' OFS='\t' helloworld.sh  //制表符分隔輸出多字段

應(yīng)用3

awk -F'[:#/]' '{print NF}' helloworld.sh                           //指定三個(gè)分隔符，并輸出每行字段數(shù)

awk -F'[:#/]' '{print $1,$2,$3,$4,$5,$6,$7,$8,$9,$10,$11,$12}' helloworld.sh    //制表符分隔輸出多字段

應(yīng)用4

計(jì)算/home目錄下，普通文件的大小，使用KB作為單位

ls -l|awk 'BEGIN{sum=0} !/^d/{sum+=$5} END{print "total size is:",sum/1024,"KB"}'

ls -l|awk 'BEGIN{sum=0} !/^d/{sum+=$5} END{print "total size is:",int(sum/1024),"KB"}'     //int是取整的意思

應(yīng)用5

統(tǒng)計(jì)netstat -anp 狀態(tài)為L(zhǎng)ISTEN和CONNECT的連接數(shù)量分別是多少

netstat -anp|awk '$6~/LISTEN|CONNECTED/{sum[$6]++} END{for (i in sum) printf "%-10s %-6s %-3s \n", i," ",sum[i]}'

應(yīng)用6

統(tǒng)計(jì)/home目錄下不同用戶的普通文件的總數(shù)是多少？

ls -l|awk 'NR!=1 && !/^d/{sum[$3]++} END{for (i in sum) printf "%-6s %-5s %-3s \n",i," ",sum[i]}'

mysql     199

root      374

統(tǒng)計(jì)/home目錄下不同用戶的普通文件的大小總size是多少？

ls -l|awk 'NR!=1 && !/^d/{sum[$3]+=$5} END{for (i in sum) printf "%-6s %-5s %-3s %-2s \n",i," ",sum[i]/1024/1024,"MB"}'

應(yīng)用7

輸出成績(jī)表

awk 'BEGIN{math=0;eng=0;com=0;printf "Lineno.  Name   No.   Math  English  Computer   Total\n";printf "------------------------------------------------------------\n"}{math+=$3; eng+=$4; com+=$5;printf "%-8s %-7s %-7s %-7s %-9s %-10s %-7s \n",NR,$1,$2,$3,$4,$5,$3+$4+$5} END{printf "------------------------------------------------------------\n";printf "%-24s %-7s %-9s %-20s \n","Total:",math,eng,com;printf "%-24s %-7s %-9s %-20s \n","Avg:",math/NR,eng/NR,com/NR}' test0

[root@localhost home]# cat test0

Marry  2143 78 84 77

Jack   2321 66 78 45

Tom   2122 48 77 71

Mike   2537 87 97 95

Bob   2415 40 57 62

另外有需要云服務(wù)器可以了解下創(chuàng)新互聯(lián)cdcxhl.cn，海內(nèi)外云服務(wù)器15元起步，三天無理由+7*72小時(shí)售后在線，公司持有idc許可證，提供“云服務(wù)器、裸金屬服務(wù)器、高防服務(wù)器、香港服務(wù)器、美國服務(wù)器、虛擬主機(jī)、免備案服務(wù)器”等云主機(jī)租用服務(wù)以及企業(yè)上云的綜合解決方案，具有“安全穩(wěn)定、簡(jiǎn)單易用、服務(wù)可用性高、性價(jià)比高”等特點(diǎn)與優(yōu)勢(shì)，專為企業(yè)上云打造定制，能夠滿足用戶豐富、多元化的應(yīng)用場(chǎng)景需求。

本文題目：awk命令學(xué)習(xí)-創(chuàng)新互聯(lián)
文章鏈接：http://aaarwkj.com/article34/pjsse.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供網(wǎng)站策劃、建站公司、網(wǎng)頁設(shè)計(jì)公司、網(wǎng)站設(shè)計(jì)公司、響應(yīng)式網(wǎng)站、軟件開發(fā)

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來源： 創(chuàng)新互聯(lián)