怎么在Oracle中創(chuàng)建一個(gè)錯(cuò)誤日志表-創(chuàng)新互聯(lián)

怎么在Oracle中創(chuàng)建一個(gè)錯(cuò)誤日志表？很多新手對(duì)此不是很清楚，為了幫助大家解決這個(gè)難題，下面小編將為大家詳細(xì)講解，有這方面需求的人可以來(lái)學(xué)習(xí)下，希望你能有所收獲。

網(wǎng)站制作、網(wǎng)站建設(shè)介紹好的網(wǎng)站是理念、設(shè)計(jì)和技術(shù)的結(jié)合。創(chuàng)新互聯(lián)建站擁有的網(wǎng)站設(shè)計(jì)理念、多方位的設(shè)計(jì)風(fēng)格、經(jīng)驗(yàn)豐富的設(shè)計(jì)團(tuán)隊(duì)。提供PC端+手機(jī)端網(wǎng)站建設(shè)，用營(yíng)銷思維進(jìn)行網(wǎng)站設(shè)計(jì)、采用先進(jìn)技術(shù)開(kāi)源代碼、注重用戶體驗(yàn)與SEO基礎(chǔ)，將技術(shù)與創(chuàng)意整合到網(wǎng)站之中，以契合客戶的方式做到創(chuàng)意性的視覺(jué)化效果。

1 概述

1. 目的：'快速定位程序異常'

2. 包處理的核心思想：'自治事務(wù)' -- 自治事務(wù)的 "提交、回滾" 與主事務(wù) 之間互不影響

3. 錯(cuò)誤異常記錄邏輯大體一致，此處記錄，方便需要使用時(shí)復(fù)制、粘貼

4. 驗(yàn)證思路：通過(guò)執(zhí)行報(bào)錯(cuò)的過(guò)程，觀察 '程序執(zhí)行結(jié)果' 和 '日志表' 數(shù)據(jù)插入情況

2 效果演示

程序執(zhí)行截圖：

怎么在Oracle中創(chuàng)建一個(gè)錯(cuò)誤日志表

日志表查詢截圖：

怎么在Oracle中創(chuàng)建一個(gè)錯(cuò)誤日志表

3 源碼

說(shuō)明：
1. 測(cè)試中，共有 2 個(gè)用戶 -- 模擬實(shí)際開(kāi)發(fā)場(chǎng)景
  (1) odsdata: 存放業(yè)務(wù)數(shù)據(jù)
  (2) odscde : 執(zhí)行具體操作
  -- 為了方便測(cè)試，也可以去掉所有 '屬主 owner'

3.1 錯(cuò)誤日志表

CREATE TABLE odsdata.ods_program_error_log (
 error_log_id    VARCHAR2(10) NOT NULL, -- CONSTRAINT pk_opel_error_log_id PRIMARY KEY(error_log_id)
 owner        VARCHAR2(30),
 package_name    VARCHAR2(30),
 procedure_name   VARCHAR2(30),
 error_comment    VARCHAR2(1000),
 error_backtrace   VARCHAR2(400),
 error_stack     VARCHAR2(4000),
 call_stack     VARCHAR2(4000),
 error_date     DATE NOT NULL,
 oracle_execute_user VARCHAR2(50),
 um_id        VARCHAR2(50)
);

COMMENT ON TABLE odsdata.ods_program_error_log IS '程序錯(cuò)誤日志表';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_log_id IS '錯(cuò)誤日志id';
COMMENT ON COLUMN odsdata.ods_program_error_log.owner IS '屬主';
COMMENT ON COLUMN odsdata.ods_program_error_log.package_name IS '包名';
COMMENT ON COLUMN odsdata.ods_program_error_log.procedure_name IS '過(guò)程名';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_comment IS '錯(cuò)誤備注';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_backtrace IS '錯(cuò)誤跟蹤';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_stack IS '錯(cuò)誤堆棧';
COMMENT ON COLUMN odsdata.ods_program_error_log.call_stack IS '調(diào)用堆棧';
COMMENT ON COLUMN odsdata.ods_program_error_log.error_date IS '錯(cuò)誤時(shí)間';
COMMENT ON COLUMN odsdata.ods_program_error_log.oracle_execute_user IS 'oracle執(zhí)行用戶';
COMMENT ON COLUMN odsdata.ods_program_error_log.um_id IS '操作人員um賬號(hào)';

GRANT SELECT, INSERT, UPDATE ON odsdata.ods_program_error_log TO odscde;

3.2 異常處理包

擴(kuò)展：Oracle 序列詳解（sequence）

package：

CREATE OR REPLACE PACKAGE odscde.pkg_ods_error_handle IS
 --*************************************************
 --功能說(shuō)明: 錯(cuò)誤日志
 --參數(shù)說(shuō)明: i_procedure_name 程序名
 --     i_error_comment  錯(cuò)誤備注（手工添加的）
 --調(diào)用函數(shù):
 --修改記錄： create by YoYo 2020-12-17
 --*************************************************
 PROCEDURE exception_handle(i_procedure_name IN VARCHAR2,
               i_error_comment IN VARCHAR2);
END pkg_ods_error_handle;

package body：

CREATE OR REPLACE PACKAGE BODY odscde.pkg_ods_error_handle IS
 --*************************************************
 --功能說(shuō)明: 錯(cuò)誤日志
 --參數(shù)說(shuō)明: i_procedure_name 程序名
 --     i_error_comment  錯(cuò)誤備注（手工添加的）
 --調(diào)用函數(shù):
 --修改記錄： create by YoYo 2020-12-17
 --*************************************************
 PROCEDURE exception_handle(i_procedure_name IN VARCHAR2,
               i_error_comment IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION; -- !!! 自治事務(wù)
  v_log_info odsdata.ods_program_error_log%ROWTYPE;
 BEGIN
  v_log_info.error_log_id    := '1'; -- 異常錯(cuò)誤id（一般是 "獲取序列號(hào)"，此處僅演示）
  v_log_info.procedure_name   := i_procedure_name; -- 程序名
  v_log_info.error_comment    := i_error_comment;
  v_log_info.oracle_execute_user := sys_context('USERENV', 'SESSION_USER'); -- oracle執(zhí)行用戶
  v_log_info.um_id        := nvl(sys_context('USERENV', 'OS_USER'),
                     USER); -- 操作人員um賬號(hào)
  v_log_info.error_backtrace   := dbms_utility.format_error_backtrace; -- 錯(cuò)誤跟蹤
  v_log_info.error_stack     := dbms_utility.format_error_stack; -- 錯(cuò)誤堆棧
  v_log_info.call_stack     := dbms_utility.format_call_stack; -- 調(diào)用堆棧
  v_log_info.error_date     := SYSDATE;
 
  -- 可選列
  ---- 包屬主
  v_log_info.owner := substr(v_log_info.error_backtrace,
                instr(v_log_info.error_backtrace, '"', 1) + 1,
                (instr(v_log_info.error_backtrace, '.', 1) -
                instr(v_log_info.error_backtrace, '"', 1) - 1));
  ---- 包名
  v_log_info.package_name := substr(v_log_info.error_backtrace,
                   instr(v_log_info.error_backtrace,
                      '.',
                      1) + 1,
                   (instr(v_log_info.error_backtrace,
                       '"',
                       1,
                       2) - instr(v_log_info.error_backtrace,
                             '.',
                             1) - 1));
 
  -- 插入數(shù)據(jù)
  INSERT INTO odsdata.ods_program_error_log
   (error_log_id,
    owner,
    package_name,
    procedure_name,
    error_comment,
    error_backtrace,
    error_stack,
    call_stack,
    error_date,
    oracle_execute_user,
    um_id)
  VALUES
   (v_log_info.error_log_id,
    v_log_info.owner,
    v_log_info.package_name,
    v_log_info.procedure_name,
    v_log_info.error_comment,
    v_log_info.error_backtrace,
    v_log_info.error_stack,
    v_log_info.call_stack,
    v_log_info.error_date,
    v_log_info.oracle_execute_user,
    v_log_info.um_id);
 
  COMMIT;
 END exception_handle;
END pkg_ods_error_handle;

3.3 測(cè)試程序

演示報(bào)錯(cuò)：違反性約束

stu_info：

CREATE TABLE odsdata.stu_info (
 sno  NUMBER(10) CONSTRAINT pk_si_sno PRIMARY KEY,
 sname VARCHAR2(50) NOT NULL
);

GRANT SELECT, INSERT, UPDATE ON odsdata.stu_info TO odscde;

INSERT INTO odsdata.stu_info(sno, sname) VALUES(1, '瑤瑤');
COMMIT;

package:

CREATE OR REPLACE PACKAGE odscde.pkg_ods_error_test AS
 PROCEDURE ods_error_test(o_flag  OUT VARCHAR2,
              o_message OUT VARCHAR2);
END pkg_ods_error_test;

package body：

CREATE OR REPLACE PACKAGE BODY odscde.pkg_ods_error_test AS
 PROCEDURE ods_error_test(o_flag  OUT VARCHAR2,
              o_message OUT VARCHAR2) IS
  i_procedure_name VARCHAR2(30) := 'ods_error_test';
 BEGIN
  INSERT INTO odsdata.stu_info (sno, sname) VALUES (1, '瑤瑤');
  COMMIT;
 
  o_flag  := 'Y';
  o_message := '執(zhí)行成功！';
 EXCEPTION
  WHEN OTHERS THEN
   o_flag  := 'N';
   o_message := '執(zhí)行失??！';
   pkg_ods_error_handle.exception_handle(i_procedure_name => i_procedure_name,
                      i_error_comment => '' -- 關(guān)鍵入?yún)?、出?                      );
 END ods_error_test;
END pkg_ods_error_test;

看完上述內(nèi)容是否對(duì)您有幫助呢？如果還想對(duì)相關(guān)知識(shí)有進(jìn)一步的了解或閱讀更多相關(guān)文章，請(qǐng)關(guān)注創(chuàng)新互聯(lián)行業(yè)資訊頻道，感謝您對(duì)創(chuàng)新互聯(lián)網(wǎng)站建設(shè)公司，的支持。

當(dāng)前題目：怎么在Oracle中創(chuàng)建一個(gè)錯(cuò)誤日志表-創(chuàng)新互聯(lián)
URL標(biāo)題：http://aaarwkj.com/article26/gcccg.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供外貿(mào)建站、建站公司、自適應(yīng)網(wǎng)站、品牌網(wǎng)站設(shè)計(jì)、網(wǎng)站建設(shè)、ChatGPT

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來(lái)源：創(chuàng)新互聯(lián)

猜你還喜歡下面的內(nèi)容